简单倒计时类的应用(as2.0)

当前位置：主页>AS 应用>文章内容

简单倒计时类的应用(as2.0)

来源：taoshaw 作者：taoshaw 2008-04-08 【大中小】

功能：设置好用于显示倒计时类的动态文本框实例名称，以及倒计时数目，包括倒计时结束后跳转到的帧数即可。
演示：

源码下载：
http://www.taoshaw.com/taoshaw/study/TaoshawCountDown/TaoshawCountDown.rar
TaoshawCountDown类中的代码如下：

/*------------------------------------------
作者：沙子
站点：http://www.taoshaw.com
版本：v1.0
版权：淘沙网
此代码定义的是一个倒计时类，可以简单的创建秒数的倒计时，可用于一般小游戏
------------------------------------------*/
//此处进行类声明，注意，类名称要与前面的as文件名一致
class TaoshawCountDown {
  //定义变量开始
  //定义重复调用函数的名称
  private var my_ID:Number;
  private var my_Second:Number;
  //定义倒计时的总时间
  private var my_Total:Number;
  //定义倒计时完后，跳转的帧数
  private var my_Frame:Number;
  static var my_Length:Number;
  //定义私有用于显示计时的场景动态文本实例
  private var my_Text:TextField;
  //构造实例函数，用于创建实例
  public function TaoshawCountDown(my_text:TextField, second:Number, my_frame:Number) {
    my_Text = my_text;
    my_Second = second;
    my_Total = second;
    my_Frame = my_frame;
    init();
  }
  //初始化计时器
  private function init():Void {
    //计时器数目递加
    TaoshawCountDown.my_Length += 1;
  }
  //获取计时的总时间
  public function get total():Number {
    return my_Total;
  }
  //设置计时的总时间
  public function set total(second:Number):Void {
    my_Second = second;
    my_Total = second;
  }
  //统计计时器的数目
  static function getLength():Number {
    return TaoshawCountDown.my_Length;
  }
  //实现计时功能
  private function timeing():Void {
    //当倒计时数目>0时，递减
    if (my_Second>0) {
      my_Text.text = String(my_Second);
      my_Second--;
    } else {
      this.stop();
    }
  }
  public function play():Void {
    my_Text.text = String(my_Second);
    //每隔1秒调用一次timeing函数
    my_ID = setInterval(this, "timeing", 1000);
  }
  //定义stop()函数
  public function stop():Void {
    my_Second = my_Total;
    my_Text.text = "计时结束";
    //清除调用函数
    clearInterval(my_ID);
    //倒计时完后跳转的帧数
    _root.gotoAndPlay(my_Frame);
  }
}
/*------------------------------------------
作者：沙子
站点：http://www.taoshaw.com
版本：v1.0
版权：淘沙网
此代码定义的是一个倒计时类，可以简单的创建秒数的倒计时，可用于一般小游戏
------------------------------------------*/

调用此类时代码：

stop();
//在此定义用于显示倒计时时间的动态文本框实例名，第二个参数为倒计时的秒数，第三个为倒计时完后，跳转的帧数
var my_time:TaoshawCountDown=new TaoshawCountDown(_text,10,2)
my_time.play();

上一篇：FLASH CS3 BUTTON组件应用开发(二) 下一篇：Flash打造随意飘飞的彩色肥皂泡(as2.0)

·鼠标控制的flash跑马灯效果(as2.0)	·抽奖机(as2.0)
·flash8：一帧做出雪景画面 (as2.0)	·随机抽取号码(13，15号段任意号码
·随机抽取号码(13，15号段任意号码	·简单的火焰效果及图示原理(as3.0)
·BitmapData抠图小实验(as3.0)	·Flash打造随意飘飞的彩色肥皂泡(as
·简单的物体二段跳效果(as3.0)	·简单倒计时类的应用(as2.0)

您的评论